/**
 *
 * SMILManager.as
 *
 *     Handles downloading and parsing SMIL xml format for fl.video.NCManager.
 *     Addresses a bug in Adobe's SMILManager whereby parseVideo() won't
 *     recognize "system-bitrate" attributes on video tags. For some reason, the
 *     version of the function included in the "Component Source" folder works
 *     fine but the compiled version doesn't. This simply overrides the faulty
 *     function with their good version of it.
 *
 *     @author     matthew at exanimo dot com
 *     @author     Ryan Sprake (<http://eightdotthree.net>)
 *     @version    2007.06.05
 *
 */
package com.exanimo.video
{


	import fl.video.flvplayback_internal;
	import fl.video.INCManager;
	import fl.video.SMILManager;


	use namespace flvplayback_internal;




	public class SMILManager extends fl.video.SMILManager
	{




		/**
		 *
         * Constructor
		 *
		 */
		public function SMILManager(owner:INCManager)
		{
			super(owner);
		} 


		/**
		 * parse video or ref node of smil.  Returns object with
		 * attribute info.
		 *
         * @private
         *
         * @langversion 3.0
         * @playerversion Flash 9.0.28.0
		 */
		flvplayback_internal override function parseVideo(node:XML):Object
		{
			var obj:Object = new Object();
			if (node.@src.length() > 0)
			{
				obj.src = node.@src.toString();
			}
			if (node.@['system-bitrate'].length() > 0)
			{
				obj.bitrate = int(node.@['system-bitrate'].toString());
			}
			if (node.@dur.length() > 0)
			{
				obj.dur = parseTime(node.@dur.toString());
			}
			return obj;
		}




	}
}